1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
|
" Tests for the 'find' command completion.
" Do all the tests in a separate window to avoid E211 when we recursively
" delete the Xfind directory during cleanup
func Test_find_complete()
set belloff=all
" On windows a stale "Xfind" directory may exist, remove it so that
" we start from a clean state.
call delete("Xfind", "rf")
let cwd = getcwd()
let test_out = cwd . '/test.out'
call mkdir('Xfind')
cd Xfind
new
set path=
call assert_fails('call feedkeys(":find\t\n", "xt")', 'E345:')
close
new
set path=.
call assert_fails('call feedkeys(":find\t\n", "xt")', 'E32:')
close
new
set path=.,,
call assert_fails('call feedkeys(":find\t\n", "xt")', 'E32:')
close
new
set path=./**
call assert_fails('call feedkeys(":find\t\n", "xt")', 'E32:')
close
" We shouldn't find any file till this point
call mkdir('in/path', 'p')
call chdir(cwd)
call writefile(['Holy Grail'], 'Xfind/file.txt')
call writefile(['Jimmy Hoffa'], 'Xfind/in/file.txt')
call writefile(['Another Holy Grail'], 'Xfind/in/stuff.txt')
call writefile(['E.T.'], 'Xfind/in/path/file.txt')
new
set path=Xfind/**
call feedkeys(":find file\t\n", "xt")
call assert_equal('Holy Grail', getline(1))
call feedkeys(":find file\t\t\n", "xt")
call assert_equal('Jimmy Hoffa', getline(1))
call feedkeys(":find file\t\t\t\n", "xt")
call assert_equal('E.T.', getline(1))
" Rerun the previous three find completions, using fullpath in 'path'
exec "set path=" . cwd . "/Xfind/**"
call feedkeys(":find file\t\n", "xt")
call assert_equal('Holy Grail', getline(1))
call feedkeys(":find file\t\t\n", "xt")
call assert_equal('Jimmy Hoffa', getline(1))
call feedkeys(":find file\t\t\t\n", "xt")
call assert_equal('E.T.', getline(1))
" Same steps again, using relative and fullpath items that point to the same
" recursive location.
" This is to test that there are no duplicates in the completion list.
set path+=Xfind/**
call feedkeys(":find file\t\n", "xt")
call assert_equal('Holy Grail', getline(1))
call feedkeys(":find file\t\t\n", "xt")
call assert_equal('Jimmy Hoffa', getline(1))
call feedkeys(":find file\t\t\t\n", "xt")
call assert_equal('E.T.', getline(1))
call feedkeys(":find file\t\t\n", "xt")
" Test find completion for directory of current buffer, which at this point
" is Xfind/in/file.txt.
set path=.
call feedkeys(":find st\t\n", "xt")
call assert_equal('Another Holy Grail', getline(1))
" Test find completion for empty path item ",," which is the current
" directory
cd Xfind
set path=,,
call feedkeys(":find f\t\n", "xt")
call assert_equal('Holy Grail', getline(1))
" Test that find completion on directory appends a slash
call feedkeys(":find in/pa\tfile.txt\n", "xt")
call assert_equal('E.T.', getline(1))
call feedkeys(":find ./i\tstuff.txt\n", "xt")
call assert_equal('Another Holy Grail', getline(1))
" Test shortening of
"
" foo/x/bar/voyager.txt
" foo/y/bar/voyager.txt
"
" When current directory is above foo/ they should be shortened to (in order
" of appearance):
"
" x/bar/voyager.txt
" y/bar/voyager.txt
call mkdir('foo/x/bar', 'p')
call mkdir('foo/y/bar', 'p')
call writefile(['Voyager 1'], 'foo/x/bar/voyager.txt')
call writefile(['Voyager 2'], 'foo/y/bar/voyager.txt')
exec "set path=" . cwd . "/Xfind/**"
call feedkeys(":find voyager\t\n", "xt")
call assert_equal('Voyager 1', getline(1))
call feedkeys(":find voyager\t\t\n", "xt")
call assert_equal('Voyager 2', getline(1))
"
" When current directory is .../foo/y/bar they should be shortened to (in
" order of appearance):
"
" ./voyager.txt
" x/bar/voyager.txt
cd foo/y/bar
call feedkeys(":find voyager\t\n", "xt")
call assert_equal('Voyager 2', getline(1))
call feedkeys(":find voyager\t\t\n", "xt")
call assert_equal('Voyager 1', getline(1))
" Check the opposite too:
cd ../../x/bar
call feedkeys(":find voyager\t\n", "xt")
call assert_equal('Voyager 1', getline(1))
call feedkeys(":find voyager\t\t\n", "xt")
call assert_equal('Voyager 2', getline(1))
" Check for correct handling of shorten_fname()'s behavior on windows
call chdir(cwd .. "/Xfind/in")
call feedkeys(":find file\t\n", "xt")
call assert_equal('Jimmy Hoffa', getline(1))
" Test for relative to current buffer 'path' item
call chdir(cwd . "/Xfind/")
set path=./path
" Open the file where Jimmy Hoffa is found
e in/file.txt
" Find the file containing 'E.T.' in the Xfind/in/path directory
call feedkeys(":find file\t\n", "xt")
call assert_equal('E.T.', getline(1))
" Test that completion works when path=.,,
set path=.,,
" Open Jimmy Hoffa file
e in/file.txt
call assert_equal('Jimmy Hoffa', getline(1))
" Search for the file containing Holy Grail in same directory as in/path.txt
call feedkeys(":find stu\t\n", "xt")
call assert_equal('Another Holy Grail', getline(1))
enew | only
call chdir(cwd)
call delete('Xfind', 'rf')
set path&
endfunc
|
