1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
vim9script
# cfilter.vim: Plugin to filter entries from a quickfix/location list
# Last Change: August 16, 2023
# Maintainer: Yegappan Lakshmanan (yegappan AT yahoo DOT com)
# Version: 2.0
#
# Commands to filter the quickfix list:
# :Cfilter[!] /{pat}/
# Create a new quickfix list from entries matching {pat} in the current
# quickfix list. Both the file name and the text of the entries are
# matched against {pat}. If ! is supplied, then entries not matching
# {pat} are used. The pattern can be optionally enclosed using one of
# the following characters: ', ", /. If the pattern is empty, then the
# last used search pattern is used.
# :Lfilter[!] /{pat}/
# Same as :Cfilter but operates on the current location list.
#
def Qf_filter(qf: bool, searchpat: string, bang: string)
var Xgetlist: func
var Xsetlist: func
var cmd: string
var firstchar: string
var lastchar: string
var pat: string
var title: string
var Cond: func
var items: list<any>
if qf
Xgetlist = function('getqflist')
Xsetlist = function('setqflist')
cmd = $':Cfilter{bang}'
else
Xgetlist = function('getloclist', [0])
Xsetlist = function('setloclist', [0])
cmd = $':Lfilter{bang}'
endif
firstchar = searchpat[0]
lastchar = searchpat[-1 :]
if firstchar == lastchar &&
(firstchar == '/' || firstchar == '"' || firstchar == "'")
pat = searchpat[1 : -2]
if pat == ''
# Use the last search pattern
pat = @/
endif
else
pat = searchpat
endif
if pat == ''
return
endif
if bang == '!'
Cond = (_, val) => val.text !~# pat && bufname(val.bufnr) !~# pat
else
Cond = (_, val) => val.text =~# pat || bufname(val.bufnr) =~# pat
endif
items = filter(Xgetlist(), Cond)
title = $'{cmd} /{pat}/'
Xsetlist([], ' ', {title: title, items: items})
enddef
command! -nargs=+ -bang Cfilter Qf_filter(true, <q-args>, <q-bang>)
command! -nargs=+ -bang Lfilter Qf_filter(false, <q-args>, <q-bang>)
# vim: shiftwidth=2 sts=2 expandtab
|