Merge pull request #53472 from borisbabic/feature/init-virtscreen

virtscreen: init at 0.3.1

4 files changed, 73 insertions, 0 deletions

diff --git a/pkgs/development/python-modules/quamash/default.nix b/pkgs/development/python-modules/quamash/default.nix
new file mode 100644
index 000000000000..b39e081c4712
--- /dev/null
+++ b/pkgs/development/python-modules/quamash/default.nix
@@ -0,0 +1,30 @@
+{ lib, buildPythonPackage, fetchFromGitHub, pytest, isPy3k, pyqt5, pyqt ? pyqt5 }:
+
+buildPythonPackage rec {
+  pname = "quamash";
+  version = "0.6.1";
+
+  disabled = !isPy3k;
+
+  # No tests in PyPi tarball
+  src = fetchFromGitHub {
+    owner = "harvimt";
+    repo = "quamash";
+    rev = "version-${version}";
+    sha256 = "117rp9r4lz0kfz4dmmpa35hp6nhbh6b4xq0jmgvqm68g9hwdxmqa";
+  };
+
+  propagatedBuildInputs = [ pyqt ];
+
+  checkInputs = [ pytest ];
+  checkPhase = ''
+     pytest -k 'test_qthreadexec.py' # the others cause the test execution to be aborted, I think because of asyncio
+  '';
+
+  meta = with lib; {
+    description = "Implementation of the PEP 3156 event-loop (asyncio) api using the Qt Event-Loop";
+    homepage = https://github.com/harvimt/quamash;
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ borisbabic ];
+  };
+}
diff --git a/pkgs/tools/admin/virtscreen/default.nix b/pkgs/tools/admin/virtscreen/default.nix
new file mode 100644
index 000000000000..73a81fcff875
--- /dev/null
+++ b/pkgs/tools/admin/virtscreen/default.nix
@@ -0,0 +1,39 @@
+{ stdenv, fetchFromGitHub, python3Packages, x11vnc, xrandr, libGL }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "virtscreen";
+  version = "0.3.1";
+
+  disabled = python3Packages.pythonOlder "3.6";
+
+  # No tests
+  doCheck = false;
+
+  src = fetchFromGitHub {
+    owner = "kbumsik";
+    repo = pname;
+    rev = version;
+    sha256 = "005qach6phz8w17k8kqmyd647c6jkfybczybxq0yxi5ik0s91a08";
+  };
+
+  propagatedBuildInputs = with python3Packages; [
+    netifaces
+    pyqt5
+    quamash
+    x11vnc
+    xrandr
+  ];
+
+  postPatch = let
+    ext = stdenv.hostPlatform.extensions.sharedLibrary; in ''
+    substituteInPlace virtscreen/__main__.py \
+      --replace "'GL'" "'${libGL}/lib/libGL${ext}'" \
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Make your iPad/tablet/computer as a secondary monitor on Linux";
+    homepage = https://github.com/kbumsik/VirtScreen;
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ borisbabic ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index a26a2c3ba26a..4ca0101f3096 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -19852,6 +19852,8 @@ in
 
   virtinst = callPackage ../applications/virtualization/virtinst {};
 
+  virtscreen = callPackage ../tools/admin/virtscreen {};
+
   virtualbox = callPackage ../applications/virtualization/virtualbox {
     stdenv = stdenv_32bit;
     inherit (gnome2) libIDL;
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index e6cb127f96db..2879cf8432a0 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -3937,6 +3937,8 @@ in {
 
   retry_decorator = callPackage ../development/python-modules/retry_decorator { };
 
+  quamash = callPackage ../development/python-modules/quamash { };
+
   quandl = callPackage ../development/python-modules/quandl { };
   # alias for an older package which did not support Python 3
   Quandl = callPackage ../development/python-modules/quandl { };