botan: Refactor into generic builder

3 files changed, 47 insertions, 116 deletions

diff --git a/pkgs/development/libraries/botan/default.nix b/pkgs/development/libraries/botan/default.nix
index 082efd0a9c29..fc56d630837c 100644
--- a/pkgs/development/libraries/botan/default.nix
+++ b/pkgs/development/libraries/botan/default.nix
@@ -1,59 +1,7 @@
-x@{builderDefsPackage
-  , python
-  , bzip2, zlib, gmp, openssl
-  , boost
-  , ...}:
-builderDefsPackage
-(a :  
-let 
-  helperArgNames = ["stdenv" "fetchurl" "builderDefsPackage"] ++ 
-    [];
+{ callPackage, ... } @ args:
 
-  buildInputs = [ ]
-    ++ map (n: builtins.getAttr n x)
-      (builtins.attrNames (builtins.removeAttrs x helperArgNames));
-  sourceInfo = rec {
-    baseName="botan";
-    tarBaseName="Botan";
-    baseVersion = "1.10";
-    revision = "8";
-    version="${baseVersion}.${revision}";
-    name="${baseName}-${version}";
-    url="http://files.randombit.net/${baseName}/v${baseVersion}/${tarBaseName}-${version}.tbz";
-    hash = "182f316rbdd6jrqn92vjms3jyb9syn4ic0nzi3b7rfjbj3zdabxw";
-  };
-in
-rec {
-  src = a.fetchurl {
-    url = sourceInfo.url;
-    sha256 = sourceInfo.hash;
-  };
-
-  inherit (sourceInfo) name version;
-  inherit buildInputs;
-
-  /* doConfigure should be removed if not needed */
-  phaseNames = ["doConfigure" "doMakeInstall" "fixPkgConfig"];
-  configureCommand = "python configure.py --with-gnump --with-bzip2 --with-zlib --with-openssl --with-tr1-implementation=boost";
-
-  fixPkgConfig = a.fullDepEntry ''
-    cd "$out"/lib/pkgconfig
-    ln -s botan-*.pc botan.pc || true
-  '' ["minInit" "doMakeInstall"];
-      
-  meta = {
-    description = "Cryptographic algorithms library";
-    maintainers = with a.lib.maintainers;
-    [
-      raskin
-    ];
-    platforms = with a.lib.platforms;
-      unix;
-    inherit version;
-  };
-  passthru = {
-    updateInfo = {
-      downloadPage = "http://files.randombit.net/botan/";
-    };
-  };
-}) x
+callPackage ./generic.nix (args // {
+  baseVersion = "1.10";
+  revision = "8";
+  sha256 = "182f316rbdd6jrqn92vjms3jyb9syn4ic0nzi3b7rfjbj3zdabxw";
+})
diff --git a/pkgs/development/libraries/botan/generic.nix b/pkgs/development/libraries/botan/generic.nix
new file mode 100644
index 000000000000..3fe8d1da7299
--- /dev/null
+++ b/pkgs/development/libraries/botan/generic.nix
@@ -0,0 +1,35 @@
+{ stdenv, fetchurl, python, bzip2, zlib, gmp, openssl, boost
+# Passed by version specific builders
+, baseVersion, revision, sha256
+, ...
+}:
+
+stdenv.mkDerivation rec {
+  name = "botan-${version}";
+  version = "${baseVersion}.${revision}";
+
+  src = fetchurl {
+    name = "Botan-${version}.tar.bz2";
+    url = "http://files.randombit.net/botan/v${baseVersion}/Botan-${version}.tbz";
+    inherit sha256;
+  };
+
+  buildInputs = [ python bzip2 zlib gmp openssl boost ];
+
+  configurePhase = ''
+    python configure.py --prefix=$out --with-gnump --with-bzip2 --with-zlib --with-openssl
+  '';
+
+  postInstall = ''
+    cd "$out"/lib/pkgconfig
+    ln -s botan-*.pc botan.pc || true
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Cryptographic algorithms library";
+    maintainers = with maintainers; [ raskin ];
+    platforms = platforms.unix;
+    license = licenses.bsd2;
+  };
+  passthru.updateInfo.downloadPage = "http://files.randombit.net/botan/";
+}
diff --git a/pkgs/development/libraries/botan/unstable.nix b/pkgs/development/libraries/botan/unstable.nix
index 9e3971978597..5b3a8720bfee 100644
--- a/pkgs/development/libraries/botan/unstable.nix
+++ b/pkgs/development/libraries/botan/unstable.nix
@@ -1,59 +1,7 @@
-x@{builderDefsPackage
-  , python
-  , bzip2, zlib, gmp, openssl
-  , boost
-  , ...}:
-builderDefsPackage
-(a :
-let
-  helperArgNames = ["stdenv" "fetchurl" "builderDefsPackage"] ++
-    [];
+{ callPackage, ... } @ args:
 
-  buildInputs = [ ]
-    ++ map (n: builtins.getAttr n x)
-      (builtins.attrNames (builtins.removeAttrs x helperArgNames));
-  sourceInfo = rec {
-    baseName="botan";
-    tarBaseName="Botan";
-    baseVersion = "1.11";
-    revision = "9";
-    version="${baseVersion}.${revision}";
-    name="${baseName}-${version}";
-    url="http://files.randombit.net/${baseName}/v${baseVersion}/${tarBaseName}-${version}.tbz";
-    hash = "0jgx5va042gmr6nc91p5dd59wnfxlz19mz2nnyv74pvwwmizs09m";
-  };
-in
-rec {
-  src = a.fetchurl {
-    url = sourceInfo.url;
-    sha256 = sourceInfo.hash;
-  };
-
-  inherit (sourceInfo) name version;
-  inherit buildInputs;
-
-  /* doConfigure should be removed if not needed */
-  phaseNames = ["doConfigure" "doMakeInstall" "fixPkgConfig"];
-  configureCommand = "python configure.py --with-gnump --with-bzip2 --with-zlib --with-openssl";
-
-  fixPkgConfig = a.fullDepEntry ''
-    cd "$out"/lib/pkgconfig
-    ln -s botan-*.pc botan.pc || true
-  '' ["minInit" "doMakeInstall"];
-
-  meta = {
-    description = "Cryptographic algorithms library";
-    maintainers = with a.lib.maintainers;
-    [
-      raskin
-    ];
-    platforms = with a.lib.platforms;
-      unix;
-    inherit version;
-  };
-  passthru = {
-    updateInfo = {
-      downloadPage = "http://files.randombit.net/botan/";
-    };
-  };
-}) x
+callPackage ./generic.nix (args // {
+  baseVersion = "1.11";
+  revision = "9";
+  sha256 = "0jgx5va042gmr6nc91p5dd59wnfxlz19mz2nnyv74pvwwmizs09m";
+})