dnl Process this file with autoconf to produce a configure script.
dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED !!!
AC_INIT([mutt],[m4_esyscmd(tr -d \\n <VERSION)])
AC_CONFIG_SRCDIR(mutt.h)
AM_INIT_AUTOMAKE
AC_CONFIG_HEADERS([config.h])
AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/VERSION'])
AC_USE_SYSTEM_EXTENSIONS
AC_CANONICAL_HOST
AC_MSG_CHECKING([for prefix])
if test x$prefix = xNONE; then
mutt_cv_prefix=$ac_default_prefix
else
mutt_cv_prefix=$prefix
fi
AC_MSG_RESULT($mutt_cv_prefix)
AC_PROG_CC
AC_PROG_CC_C99
if test "x$ac_cv_prog_cc_c99" = "xno"; then
AC_MSG_ERROR(A C99 compliant compiler is required)
fi
AC_SEARCH_LIBS([strerror],[cposix])
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_PROG_INSTALL
AC_PROG_MKDIR_P
AC_PROG_RANLIB
AC_CHECK_TOOL(AR, ar, ar)
AC_CACHE_CHECK([for GNU make],
[mutt_cv_gnu_make_command],
[mutt_cv_gnu_make_command="no"
if ${MAKE:-make} --version 2> /dev/null | grep "GNU Make" 2>&1 > /dev