blob: e31d004a82f15ffd78964d87d1a01a56481169be (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
# This file is part of Mixxx, Digital DJ'ing software.
# Copyright (C) 2001-2020 Mixxx Development Team
# Distributed under the GNU General Public Licence (GPL) version 2 or any later
# later version. See the LICENSE file for details.
#[=======================================================================[.rst:
FindGPerfTools
--------------
Finds the GPerfTools library.
Imported Targets
^^^^^^^^^^^^^^^^
This module provides the following imported targets, if found:
``GPerfTools::tcmalloc``
The GPerfTools tcmalloc library
``GPerfTools::profiler``
The GPerfTools profiler library
Result Variables
^^^^^^^^^^^^^^^^
This will define the following variables:
``GPerfTools_FOUND``
True if the system has the GPerfTools library.
``GPerfTools_INCLUDE_DIRS``
Include directories needed to use GPerfTools.
``GPerfTools_LIBRARIES``
Libraries needed to link to GPerfTools.
``GPerfTools_DEFINITIONS``
Compile definitions needed to use GPerfTools.
Cache Variables
^^^^^^^^^^^^^^^
The following cache variables may also be set:
``GPerfTools_TCMALLOC_INCLUDE_DIR``
The directory containing ``gperftools/tcmalloc.h``.
``GPerfTools_TCMALLOC_LIBRARY``
The path to the GPerfTools tcmalloc library.
``GPerfTools_PROFILER_INCLUDE_DIR``
The directory containing ``gperftools/profiler.h``.
``GPerfTools_PROFILER_LIBRARY``
The path to the GPerfTools profiler library.
#]=======================================================================]
find_package(PkgConfig QUIET)
if(PkgConfig_FOUND)
pkg_check_modules(PC_GPerfTools_TCMALLOC QUIET libtcmalloc)
pkg_check_modules(PC_GPerfTools_PROFILER QUIET libprofiler)
endif()
find_path(GPerfTools_TCMALLOC_INCLUDE_DIR
NAMES gperftools/tcmalloc.h
PATHS ${PC_GPerfTools_TCMALLOC_INCLUDE_DIRS}
DOC "tcmalloc include directory")
mark_as_advanced(GPerfTools_TCMALLOC_INCLUDE_DIR)
find_library(GPerfTools_TCMALLOC_LIBRARY
NAMES tcmalloc
PATHS ${PC_GPerfTools_TCMALLOC_LIBRARY_DIRS}
DOC "tcmalloc library"
)
mark_as_advanced(GPerfTools_TCMALLOC_LIBRARY)
find_path(GPerfTools_PROFILER_INCLUDE_DIR
NAMES gperftools/profiler.h
PATHS ${PC_GPerfTools_PROFILER_INCLUDE_DIRS}
DOC "profiler include directory")
mark_as_advanced(GPerfTools_PROFILER_INCLUDE_DIR)
find_library(GPerfTools_PROFILER_LIBRARY
NAMES profiler
PATHS ${PC_GPerfTools_PROFILER_LIBRARY_DIRS}
DOC "profiler library"
)
mark_as_advanced(GPerfTools_PROFILER_LIBRARY)
include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(
GPerfTools
DEFAULT_MSG
GPerfTools_TCMALLOC_LIBRARY
GPerfTools_TCMALLOC_INCLUDE_DIR
GPerfTools_PROFILER_LIBRARY
GPerfTools_PROFILER_INCLUDE_DIR
)
if(GPerfTools_FOUND)
set(GPerfTools_LIBRARIES
${GPerfTools_TCMALLOC_LIBRARY}
${GPerfTools_PROFILER_LIBRARY}
)
set(GPerfTools_INCLUDE_DIRS
${GPerfTools_TCMALLOC_INCLUDE_DIR}
${GPerfTools_PROFILER_INCLUDE_DIR}
)
set(GPerfTools_DEFINITIONS
${PC_GPerfTools_TCMALLOC_CFLAGS_OTHER}
${PC_GPerfTools_PROFILER_CFLAGS_OTHER}
)
if (NOT TARGET GPerfTools::tcmalloc)
add_library(GPerfTools::tcmalloc UNKNOWN IMPORTED)
set_target_properties(GPerfTools::tcmalloc PROPERTIES
IMPORTED_LOCATION ${GPerfTools_TCMALLOC_LIBRARY}
INTERFACE_COMPILE_OPTIONS "${PC_GPerfTools_TCMALLOC_CFLAGS_OTHER}"
INTERFACE_INCLUDE_DIRECTORIES "${GPerfTools_TCMALLOC_INCLUDE_DIR}")
endif()
if (NOT TARGET GPerfTools::profiler)
add_library(GPerfTools::profiler UNKNOWN IMPORTED)
set_target_properties(GPerfTools::profiler PROPERTIES
IMPORTED_LOCATION "${GPerfTools_PROFILER_LIBRARY}"
INTERFACE_COMPILE_OPTIONS "${PC_GPerfTools_PROFILER_CFLAGS_OTHER}"
INTERFACE_INCLUDE_DIRECTORIES "${GPerfTools_PROFILER_INCLUDE_DIR}")
endif()
endif()
|
