blob: cb6412a5655cd8c7132e5f3f2d3c54f430578d26 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
#----------------------------------------------------------
# #
# QtPass is a GUI for pass, #
# the standard unix password manager. #
# #
# Project started by Anne Jan Brouwer 2014-07-30T21:56:15 #
# #
#----------------------------------------------------------
VERSION = 1.0.4
TEMPLATE = app
QT += core gui
isEmpty(QMAKE_LRELEASE) {
win32|os2:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\\lrelease.exe
else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
unix {
!exists($$QMAKE_LRELEASE) { QMAKE_LRELEASE = lrelease-qt4 }
} else {
!exists($$QMAKE_LRELEASE) { QMAKE_LRELEASE = lrelease }
}
}
updateqm.input = TRANSLATIONS
updateqm.output = localization/${QMAKE_FILE_BASE}.qm
updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm localization/${QMAKE_FILE_BASE}.qm
updateqm.CONFIG += no_link target_predeps
QMAKE_EXTRA_COMPILERS += updateqm
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
macx {
TARGET = QtPass
QMAKE_MAC_SDK = macosx
} else {
TARGET = qtpass
}
SOURCES += main.cpp\
mainwindow.cpp \
configdialog.cpp \
storemodel.cpp \
util.cpp \
usersdialog.cpp \
keygendialog.cpp \
progressindicator.cpp \
trayicon.cpp \
passworddialog.cpp
HEADERS += mainwindow.h \
configdialog.h \
storemodel.h \
util.h \
usersdialog.h \
keygendialog.h \
progressindicator.h \
trayicon.h \
passworddialog.h
FORMS += mainwindow.ui \
configdialog.ui \
usersdialog.ui \
keygendialog.ui \
passworddialog.ui
QMAKE_CXXFLAGS_WARN_ON += -Wno-unknown-pragmas
nosingleapp {
QMAKE_CXXFLAGS += -DSINGLE_APP=0
} else {
SOURCES += singleapplication.cpp
HEADERS += singleapplication.h
QT += network
QMAKE_CXXFLAGS += -DSINGLE_APP=1
}
TRANSLATIONS += localization/localization_nl_NL.ts \
localization/localization_de_DE.ts \
localization/localization_es_ES.ts \
localization/localization_gl_ES.ts \
localization/localization_hu_HU.ts \
localization/localization_sv_SE.ts \
localization/localization_pl_PL.ts \
localization/localization_ru_RU.ts \
localization/localization_he_IL.ts \
localization/localization_zh_CN.ts \
localization/localization_ar_MA.ts
CODECFORSRC = UTF-8
CODECFORTR = UTF-8
RESOURCES += resources.qrc
win32 {
RC_FILE = windows.rc
static {
QMAKE_LFLAGS += -static-libgcc -static-libstdc++
}
QMAKE_LFLAGS += -Wl,--dynamicbase -Wl,--nxcompat
LIBS += -lmpr
} else:macx {
ICON = artwork/icon.icns
QMAKE_INFO_PLIST = Info.plist
} else:bsd {
LIBS += -L/usr/local/lib
}
OTHER_FILES += LICENSE \
README.md
isEmpty(PREFIX) {
PREFIX = $$(PREFIX)
}
isEmpty(PREFIX) {
PREFIX = /usr/local/bin
}
target.path = $$PREFIX/
INSTALLS += target
DEFINES += "VERSION=\"\\\"$$VERSION\\\"\""
|