diff options
author | Harel Ben-Attia <harelba@gmail.com> | 2014-12-13 09:53:54 -0500 |
---|---|---|
committer | Harel Ben-Attia <harelba@gmail.com> | 2014-12-13 09:53:54 -0500 |
commit | d584bb68b0f6950e59bb4efcdf30e4ba5c6d9ad9 (patch) | |
tree | d01e50fb1964af90e63039256295f4fea11381d7 /dist | |
parent | 95d3aed6e54f52dbbe3f702874e6def7f861fa45 (diff) |
Formalized windows build...
Diffstat (limited to 'dist')
-rw-r--r-- | dist/AddToPath.nsh | 440 | ||||
-rwxr-xr-x | dist/create-rpm | 2 | ||||
-rw-r--r-- | dist/create-windows-setup-instructions | 41 | ||||
-rw-r--r-- | dist/q-TextAsData-with-path.nsi | 182 |
4 files changed, 664 insertions, 1 deletions
diff --git a/dist/AddToPath.nsh b/dist/AddToPath.nsh new file mode 100644 index 0000000..b961a1f --- /dev/null +++ b/dist/AddToPath.nsh @@ -0,0 +1,440 @@ +!ifndef _AddToPath_nsh +!define _AddToPath_nsh + +!verbose 3 +!include "WinMessages.NSH" +!verbose 4 + +!ifndef WriteEnvStr_RegKey + !ifdef ALL_USERS + !define WriteEnvStr_RegKey \ + 'HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment"' + !else + !define WriteEnvStr_RegKey 'HKCU "Environment"' + !endif +!endif + +; AddToPath - Adds the given dir to the search path. +; Input - head of the stack +; Note - Win9x systems requires reboot + +Function AddToPath + Exch $0 + Push $1 + Push $2 + Push $3 + + # don't add if the path doesn't exist + IfFileExists "$0\*.*" "" AddToPath_done + + ReadEnvStr $1 PATH + Push "$1;" + Push "$0;" + Call StrStr + Pop $2 + StrCmp $2 "" "" AddToPath_done + Push "$1;" + Push "$0\;" + Call StrStr + Pop $2 + StrCmp $2 "" "" AddToPath_done + GetFullPathName /SHORT $3 $0 + Push "$1;" + Push "$3;" + Call StrStr + Pop $2 + StrCmp $2 "" "" AddToPath_done + Push "$1;" + Push "$3\;" + Call StrStr + Pop $2 + StrCmp $2 "" "" AddToPath_done + + Call IsNT + Pop $1 + StrCmp $1 1 AddToPath_NT + ; Not on NT + StrCpy $1 $WINDIR 2 + FileOpen $1 "$1\autoexec.bat" a + FileSeek $1 -1 END + FileReadByte $1 $2 + IntCmp $2 26 0 +2 +2 # DOS EOF + FileSeek $1 -1 END # write over EOF + FileWrite $1 "$\r$\nSET PATH=%PATH%;$3$\r$\n" + FileClose $1 + SetRebootFlag true + Goto AddToPath_done + + AddToPath_NT: + ReadRegStr $1 ${WriteEnvStr_RegKey} "PATH" + StrCmp $1 "" AddToPath_NTdoIt + Push $1 + Call Trim + Pop $1 + StrCpy $0 "$1;$0" + AddToPath_NTdoIt: + WriteRegExpandStr ${WriteEnvStr_RegKey} "PATH" $0 + SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000 + + AddToPath_done: + Pop $3 + Pop $2 + Pop $1 + Pop $0 +FunctionEnd + +; RemoveFromPath - Remove a given dir from the path +; Input: head of the stack + +Function un.RemoveFromPath + Exch $0 + Push $1 + Push $2 + Push $3 + Push $4 + Push $5 + Push $6 + + IntFmt $6 "%c" 26 # DOS EOF + + Call un.IsNT + Pop $1 + StrCmp $1 1 unRemoveFromPath_NT + ; Not on NT + StrCpy $1 $WINDIR 2 + FileOpen $1 "$1\autoexec.bat" r + GetTempFileName $4 + FileOpen $2 $4 w + GetFullPathName /SHORT $0 $0 + StrCpy $0 "SET PATH=%PATH%;$0" + Goto unRemoveFromPath_dosLoop + + unRemoveFromPath_dosLoop: + FileRead $1 $3 + StrCpy $5 $3 1 -1 # read last char + StrCmp $5 $6 0 +2 # if DOS EOF + StrCpy $3 $3 -1 # remove DOS EOF so we can compare + StrCmp $3 "$0$\r$\n" unRemoveFromPath_dosLoopRemoveLine + StrCmp $3 "$0$\n" unRemoveFromPath_dosLoopRemoveLine + StrCmp $3 "$0" unRemoveFromPath_dosLoopRemoveLine + StrCmp $3 "" unRemoveFromPath_dosLoopEnd + FileWrite $2 $3 + Goto unRemoveFromPath_dosLoop + unRemoveFromPath_dosLoopRemoveLine: + SetRebootFlag true + Goto unRemoveFromPath_dosLoop + + unRemoveFromPath_dosLoopEnd: + FileClose $2 + FileClose $1 + StrCpy $1 $WINDIR 2 + Delete "$1\autoexec.bat" + CopyFiles /SILENT $4 "$1\autoexec.bat" + Delete $4 + Goto unRemoveFromPath_done + + unRemoveFromPath_NT: + ReadRegStr $1 ${WriteEnvStr_RegKey} "PATH" + StrCpy $5 $1 1 -1 # copy last char + StrCmp $5 ";" +2 # if last char != ; + StrCpy $1 "$1;" # append ; + Push $1 + Push "$0;" + Call un.StrStr ; Find `$0;` in $1 + Pop $2 ; pos of our dir + StrCmp $2 "" unRemoveFromPath_done + ; else, it is in path + # $0 - path to add + # $1 - path var + StrLen $3 "$0;" + StrLen $4 $2 + StrCpy $5 $1 -$4 # $5 is now the part before the path to remove + StrCpy $6 $2 "" $3 # $6 is now the part after the path to remove + StrCpy $3 $5$6 + + StrCpy $5 $3 1 -1 # copy last char + StrCmp $5 ";" 0 +2 # if last char == ; + StrCpy $3 $3 -1 # remove last char + + WriteRegExpandStr ${WriteEnvStr_RegKey} "PATH" $3 + SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000 + + unRemoveFromPath_done: + Pop $6 + Pop $5 + Pop $4 + Pop $3 + Pop $2 + Pop $1 + Pop $0 +FunctionEnd + + + +; AddToEnvVar - Adds the given value to the given environment var +; Input - head of the stack $0 environement variable $1=value to add +; Note - Win9x systems requires reboot + +Function AddToEnvVar + + Exch $1 ; $1 has environment variable value + Exch + Exch $0 ; $0 has environment variable name + + DetailPrint "Adding $1 to $0" + Push $2 + Push $3 + Push $4 + + + ReadEnvStr $2 $0 + Push "$2;" + Push "$1;" + Call StrStr + Pop $3 + StrCmp $3 "" "" AddToEnvVar_done + + Push "$2;" + Push "$1\;" + Call StrStr + Pop $3 + StrCmp $3 "" "" AddToEnvVar_done + + + Call IsNT + Pop $2 + StrCmp $2 1 AddToEnvVar_NT + ; Not on NT + StrCpy $2 $WINDIR 2 + FileOpen $2 "$2\autoexec.bat" a + FileSeek $2 -1 END + FileReadByte $2 $3 + IntCmp $3 26 0 +2 +2 # DOS EOF + FileSeek $2 -1 END # write over EOF + FileWrite $2 "$\r$\nSET $0=%$0%;$4$\r$\n" + FileClose $2 + SetRebootFlag true + Goto AddToEnvVar_done + + AddToEnvVar_NT: + ReadRegStr $2 ${WriteEnvStr_RegKey} $0 + StrCpy $3 $2 1 -1 # copy last char + StrCmp $3 ";" 0 +2 # if last char == ; + StrCpy $2 $2 -1 # remove last char + StrCmp $2 "" AddToEnvVar_NTdoIt + StrCpy $1 "$2;$1" + AddToEnvVar_NTdoIt: + WriteRegExpandStr ${WriteEnvStr_RegKey} $0 $1 + SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000 + + AddToEnvVar_done: + Pop $4 + Pop $3 + Pop $2 + Pop $0 + Pop $1 + +FunctionEnd + +; RemoveFromEnvVar - Remove a given value from a environment var +; Input: head of the stack + +Function un.RemoveFromEnvVar + + Exch $1 ; $1 has environment variable value + Exch + Exch $0 ; $0 has environment variable name + + DetailPrint "Removing $1 from $0" + Push $2 + Push $3 + Push $4 + Push $5 + Push $6 + Push $7 + + IntFmt $7 "%c" 26 # DOS EOF + + Call un.IsNT + Pop $2 + StrCmp $2 1 unRemoveFromEnvVar_NT + ; Not on NT + StrCpy $2 $WINDIR 2 + FileOpen $2 "$2\autoexec.bat" r + GetTempFileName $5 + FileOpen $3 $5 w + GetFullPathName /SHORT $1 $1 + StrCpy $1 "SET $0=%$0%;$1" + Goto unRemoveFromEnvVar_dosLoop + + unRemoveFromEnvVar_dosLoop: + FileRead $2 $4 + StrCpy $6 $4 1 -1 # read last char + StrCmp $6 $7 0 +2 # if DOS EOF + StrCpy $4 $4 -1 # remove DOS EOF so we can compare + StrCmp $4 "$1$\r$\n" unRemoveFromEnvVar_dosLoopRemoveLine + StrCmp $4 "$1$\n" unRemoveFromEnvVar_dosLoopRemoveLine + StrCmp $4 "$1" unRemoveFromEnvVar_dosLoopRemoveLine + StrCmp $4 "" unRemoveFromEnvVar_dosLoopEnd + FileWrite $3 $4 + Goto unRemoveFromEnvVar_dosLoop + unRemoveFromEnvVar_dosLoopRemoveLine: + SetRebootFlag true + Goto unRemoveFromEnvVar_dosLoop + + unRemoveFromEnvVar_dosLoopEnd: + FileClose $3 + FileClose $2 + StrCpy $2 $WINDIR 2 + Delete "$2\autoexec.bat" + CopyFiles /SILENT $5 "$2\autoexec.bat" + Delete $5 + Goto unRemoveFromEnvVar_done + + unRemoveFromEnvVar_NT: + ReadRegStr $2 ${WriteEnvStr_RegKey} $0 + StrCpy $6 $2 1 -1 # copy last char + StrCmp $6 ";" +2 # if last char != ; + StrCpy $2 "$2;" # append ; + Push $2 + Push "$1;" + Call un.StrStr ; Find `$1;` in $2 + Pop $3 ; pos of our dir + StrCmp $3 "" unRemoveFromEnvVar_done + ; else, it is in path + # $1 - path to add + # $2 - path var + StrLen $4 "$1;" + StrLen $5 $3 + StrCpy $6 $2 -$5 # $6 is now the part before the path to remove + StrCpy $7 $3 "" $4 # $7 is now the part after the path to remove + StrCpy $4 $6$7 + + StrCpy $6 $4 1 -1 # copy last char + StrCmp $6 ";" 0 +2 # if last char == ; + StrCpy $4 $4 -1 # remove last char + + WriteRegExpandStr ${WriteEnvStr_RegKey} $0 $4 + + ; delete reg value if null + StrCmp $4 "" 0 +2 # if null delete reg + DeleteRegValue ${WriteEnvStr_RegKey} $0 + + SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000 + + unRemoveFromEnvVar_done: + Pop $7 + Pop $6 + Pop $5 + Pop $4 + Pop $3 + Pop $2 + Pop $1 + Pop $0 +FunctionEnd + + + + +!ifndef IsNT_KiCHiK +!define IsNT_KiCHiK + +########################################### +# Utility Functions # +########################################### + +; IsNT +; no input +; output, top of the stack = 1 if NT or 0 if not +; +; Usage: +; Call IsNT +; Pop $R0 +; ($R0 at this point is 1 or 0) + +!macro IsNT un +Function ${un}IsNT + Push $0 + ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" CurrentVersion + StrCmp $0 "" 0 IsNT_yes + ; we are not NT. + Pop $0 + Push 0 + Return + + IsNT_yes: + ; NT!!! + Pop $0 + Push 1 +FunctionEnd +!macroend +!insertmacro IsNT "" +!insertmacro IsNT "un." + +!endif ; IsNT_KiCHiK + +; StrStr +; input, top of stack = string to search for +; top of stack-1 = string to search in +; output, top of stack (replaces with the portion of the string remaining) +; modifies no other variables. +; +; Usage: +; Push "this is a long ass string" +; Push "ass" +; Call StrStr +; Pop $R0 +; ($R0 at this point is "ass string") + +!macro StrStr un +Function ${un}StrStr +Exch $R1 ; st=haystack,old$R1, $R1=needle + Exch ; st=old$R1,haystack + Exch $R2 ; st=old$R1,old$R2, $R2=haystack + Push $R3 + Push $R4 + Push $R5 + StrLen $R3 $R1 + StrCpy $R4 0 + ; $R1=needle + ; $R2=haystack + ; $R3=len(needle) + ; $R4=cnt + ; $R5=tmp + loop: + StrCpy $R5 $R2 $R3 $R4 + StrCmp $R5 $R1 done + StrCmp $R5 "" done + IntOp $R4 $R4 + 1 + Goto loop +done: + StrCpy $R1 $R2 "" $R4 + Pop $R5 + Pop $R4 + Pop $R3 + Pop $R2 + Exch $R1 +FunctionEnd +!macroend +!insertmacro StrStr "" +!insertmacro StrStr "un." + +Function Trim ; Added by Pelaca + Exch $R1 + Push $R2 +Loop: + StrCpy $R2 "$R1" 1 -1 + StrCmp "$R2" " " RTrim + StrCmp "$R2" "$\n" RTrim + StrCmp "$R2" "$\r" RTrim + StrCmp "$R2" ";" RTrim + GoTo Done +RTrim: + StrCpy $R1 "$R1" -1 + Goto Loop +Done: + Pop $R2 + Exch $R1 +FunctionEnd + +!endif ; _AddToPath_nsh diff --git a/dist/create-rpm b/dist/create-rpm index 465cc9f..a841db5 100755 --- a/dist/create-rpm +++ b/dist/create-rpm @@ -46,6 +46,6 @@ curl -o ${rpm_build_area}/SOURCES/q-${COMMIT_HASH}.tar.gz -L -R "https://github. cat ${RPM_PACKAGE_NAME}.spec.template | sed "s/VERSION_PLACEHOLDER/$VERSION/g" | sed "s/COMMIT_HASH_PLACEHOLDER/${COMMIT_HASH}/g" | sed "s/SHORT_HASH_PLACEHOLDER/${SHORT_HASH}/g" > ${rpm_build_area}/SPECS/${RPM_PACKAGE_NAME}.spec -rpmbuild -v --define "_topdir ${rpm_build_area}" -bb ${rpm_build_area}/SPECS/${RPM_PACKAGE_NAME}.spec +rpmbuild -v --define "_topdir ${rpm_build_area}" -ba ${rpm_build_area}/SPECS/${RPM_PACKAGE_NAME}.spec popd >/dev/null diff --git a/dist/create-windows-setup-instructions b/dist/create-windows-setup-instructions new file mode 100644 index 0000000..bf414e9 --- /dev/null +++ b/dist/create-windows-setup-instructions @@ -0,0 +1,41 @@ +
+Instructions for creating a windows package for q:
+
+1. Prepare the environment:
+
+ a. Drive Q: needs to point to the source code folder (use VirtualBox's shared folder or checkout from it and map it to Q:)
+
+ b. Create C:\q-build-environment folder
+
+ c. Install the following:
+
+ 1. Python 2.7 (32 bit) - Make sure to add python.exe to the path in the installation instructions
+ 2. Pywin32 - pywin32-219.win32-py2.7.exe (make sure it's 32 bit)
+ 3. PyInstaller 2.1 (Extract the zip file into c:\q-build-environment\ so the files will reside in c:\q-build-environment\PyInstaller-2.1\)
+ 4. NSIS - nsis-2.46-setup.exe (into c:\q-build-environment\nsis)
+
+2. Go to q:\dist and remove the folder
+
+3. Remove the folder win_output, win_build and any setup*.exe files from q:\dist
+
+4. Run the following to compile q.exe:
+
+ python.exe c:\q-build-environment\PyInstaller-2.1\pyinstaller.py -F --distpath=win_output --workpath=win_build q:\bin\q
+
+ output will reside in win_output\
+
+5. Run the following in order to package it to an installer:
+
+ Make sure to set the version number properly - Note that windows requires versions to be in the format X.X.X.X
+
+ c:\q-build-environment\nsis\makensis.exe -DVERSION=<version-number> q-TextAsData-with-path.nsi
+
+ setup.exe will reside in the current folder
+
+6. Rename the file to the proper version:
+
+ ren q:\dist\setup.exe q:\dist\setup-<version-number>.exe
+
+7. Put the file in the packages-for-q repository
+
+
diff --git a/dist/q-TextAsData-with-path.nsi b/dist/q-TextAsData-with-path.nsi new file mode 100644 index 0000000..f2bec1e --- /dev/null +++ b/dist/q-TextAsData-with-path.nsi @@ -0,0 +1,182 @@ +############################################################################################
+# NSIS Installation Script created by NSIS Quick Setup Script Generator v1.09.18
+# Entirely Edited with NullSoft Scriptable Installation System
+# by Vlasis K. Barkas aka Red Wine red_wine@freemail.gr Sep 2006
+############################################################################################
+
+!define APP_NAME "q-TextAsData"
+!define COMP_NAME "harelba"
+!define WEB_SITE "http://harelba.github.io/q/"
+# REQUIRED TO BE DEFINED EXTERNALLY !define VERSION "1.5.0.0"
+!define COPYRIGHT "Harel Ben-Attia @ 2012-2014"
+!define DESCRIPTION "Application"
+!define LICENSE_TXT "..\doc\LICENSE"
+!define INSTALLER_NAME "setup.exe"
+!define MAIN_APP_EXE "q.exe"
+!define INSTALL_TYPE "SetShellVarContext all"
+!define REG_ROOT "HKLM"
+!define REG_APP_PATH "Software\Microsoft\Windows\CurrentVersion\App Paths\${MAIN_APP_EXE}"
+!define UNINSTALL_PATH "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}"
+
+!ifndef VERSION
+ Abort ; VERSION has to be defined externally
+!endif
+######################################################################
+
+VIProductVersion "${VERSION}"
+VIAddVersionKey "ProductName" "${APP_NAME}"
+VIAddVersionKey "CompanyName" "${COMP_NAME}"
+VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
+VIAddVersionKey "FileDescription" "${DESCRIPTION}"
+VIAddVersionKey "FileVersion" "${VERSION}"
+
+######################################################################
+
+SetCompressor ZLIB
+Name "${APP_NAME}"
+Caption "${APP_NAME}"
+OutFile "${INSTALLER_NAME}"
+BrandingText "${APP_NAME}"
+XPStyle on
+InstallDirRegKey "${REG_ROOT}" "${REG_APP_PATH}" ""
+InstallDir "$PROGRAMFILES\q-TextAsData"
+
+######################################################################
+
+!include "AddToPath.nsh"
+
+
+!include "MUI.nsh"
+
+!define MUI_ABORTWARNING
+!define MUI_UNABORTWARNING
+
+!insertmacro MUI_PAGE_WELCOME
+
+!ifdef LICENSE_TXT
+!insertmacro MUI_PAGE_LICENSE "${LICENSE_TXT}"
+!endif
+
+!ifdef REG_START_MENU
+!define MUI_STARTMENUPAGE_NODISABLE
+!define MUI_STARTMENUPAGE_DEFAULTFOLDER "q-TextAsData"
+!define MUI_STARTMENUPAGE_REGISTRY_ROOT "${REG_ROOT}"
+!define MUI_STARTMENUPAGE_REGISTRY_KEY "${UNINSTALL_PATH}"
+!define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "${REG_START_MENU}"
+!insertmacro MUI_PAGE_STARTMENU Application $SM_Folder
+!endif
+
+!insertmacro MUI_PAGE_INSTFILES
+
+!insertmacro MUI_PAGE_FINISH
+
+!insertmacro MUI_UNPAGE_CONFIRM
+
+!insertmacro MUI_UNPAGE_INSTFILES
+
+!insertmacro MUI_UNPAGE_FINISH
+
+!insertmacro MUI_LANGUAGE "English"
+
+######################################################################
+
+Section -MainProgram
+${INSTALL_TYPE}
+SetOverwrite ifnewer
+SetOutPath "$INSTDIR"
+File "q:\dist\win_output\q.exe"
+
+Push $INSTDIR
+Call AddToPath
+SectionEnd
+
+######################################################################
+
+Section -Icons_Reg
+SetOutPath "$INSTDIR"
+WriteUninstaller "$INSTDIR\uninstall.exe"
+
+!ifdef REG_START_MENU
+!insertmacro MUI_STARTMENU_WRITE_BEGIN Application
+CreateDirectory "$SMPROGRAMS\$SM_Folder"
+CreateShortCut "$SMPROGRAMS\$SM_Folder\${APP_NAME}.lnk" "$INSTDIR\${MAIN_APP_EXE}"
+!ifdef WEB_SITE
+WriteIniStr "$INSTDIR\${APP_NAME} website.url" "InternetShortcut" "URL" "${WEB_SITE}"
+CreateShortCut "$SMPROGRAMS\$SM_Folder\${APP_NAME} Website.lnk" "$INSTDIR\${APP_NAME} website.url"
+!endif
+!insertmacro MUI_STARTMENU_WRITE_END
+!endif
+
+!ifndef REG_START_MENU
+CreateDirectory "$SMPROGRAMS\q-TextAsData"
+CreateShortCut "$SMPROGRAMS\q-TextAsData\${APP_NAME}.lnk" "$INSTDIR\${MAIN_APP_EXE}"
+!ifdef WEB_SITE
+WriteIniStr "$INSTDIR\${APP_NAME} website.url" "InternetShortcut" "URL" "${WEB_SITE}"
+CreateShortCut "$SMPROGRAMS\q-TextAsData\${APP_NAME} Website.lnk" "$INSTDIR\${APP_NAME} website.url"
+!endif
+!endif
+
+CreateShortCut "$SMPROGRAMS\q-TextAsData\Uninstall ${APP_NAME}.lnk" "$INSTDIR\uninstall.exe"
+
+WriteRegStr ${REG_ROOT} "${REG_APP_PATH}" "" "$INSTDIR\${MAIN_APP_EXE}"
+WriteRegStr ${REG_ROOT} "${UNINSTALL_PATH}" "DisplayName" "${APP_NAME}"
+WriteRegStr ${REG_ROOT} "${UNINSTALL_PATH}" "UninstallString" "$INSTDIR\uninstall.exe"
+WriteRegStr ${REG_ROOT} "${UNINSTALL_PATH}" "DisplayIcon" "$INSTDIR\${MAIN_APP_EXE}"
+WriteRegStr ${REG_ROOT} "${UNINSTALL_PATH}" "DisplayVersion" "${VERSION}"
+WriteRegStr ${REG_ROOT} "${UNINSTALL_PATH}" "Publisher" "${COMP_NAME}"
+
+!ifdef WEB_SITE
+WriteRegStr ${REG_ROOT} "${UNINSTALL_PATH}" "URLInfoAbout" "${WEB_SITE}"
+!endif
+SectionEnd
+
+######################################################################
+
+Section Uninstall
+
+Push $INSTDIR
+Call un.RemoveFromPath
+
+${INSTALL_TYPE}
+Delete "$INSTDIR\select.pyd"
+Delete "$INSTDIR\unicodedata.pyd"
+Delete "$INSTDIR\library.zip"
+Delete "$INSTDIR\bz2.pyd"
+Delete "$INSTDIR\sqlite3.dll"
+Delete "$INSTDIR\q.exe"
+Delete "$INSTDIR\w9xpopen.exe"
+Delete "$INSTDIR\python27.dll"
+Delete "$INSTDIR\_sqlite3.pyd"
+Delete "$INSTDIR\_hashlib.pyd"
+
+
+Delete "$INSTDIR\uninstall.exe"
+!ifdef WEB_SITE
+Delete "$INSTDIR\${APP_NAME} website.url"
+!endif
+
+RmDir "$INSTDIR"
+
+!ifdef REG_START_MENU
+!insertmacro MUI_STARTMENU_GETFOLDER "Application" $SM_Folder
+Delete "$SMPROGRAMS\$SM_Folder\${APP_NAME}.lnk"
+!ifdef WEB_SITE
+Delete "$SMPROGRAMS\$SM_Folder\${APP_NAME} Website.lnk"
+!endif
+RmDir "$SMPROGRAMS\$SM_Folder"
+!endif
+
+!ifndef REG_START_MENU
+Delete "$SMPROGRAMS\q-TextAsData\${APP_NAME}.lnk"
+!ifdef WEB_SITE
+Delete "$SMPROGRAMS\q-TextAsData\${APP_NAME} Website.lnk"
+!endif
+RmDir "$SMPROGRAMS\q-TextAsData"
+!endif
+
+DeleteRegKey ${REG_ROOT} "${REG_APP_PATH}"
+DeleteRegKey ${REG_ROOT} "${UNINSTALL_PATH}"
+SectionEnd
+
+######################################################################
+
|