blob: 285a16286497a7cb163ea4341c7112545b2b8051 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
{ fetchFromGitHub, lib, stdenv, cmake, openssl, zlib, libuv }:
let
generic = { version, sha256 }: stdenv.mkDerivation rec {
pname = "libwebsockets";
inherit version;
src = fetchFromGitHub {
owner = "warmcat";
repo = "libwebsockets";
rev = "v${version}";
inherit sha256;
};
buildInputs = [ openssl zlib libuv ];
nativeBuildInputs = [ cmake ];
cmakeFlags = [
"-DLWS_WITH_PLUGINS=ON"
"-DLWS_WITH_IPV6=ON"
"-DLWS_WITH_SOCKS5=ON"
];
NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isGNU "-Wno-error=unused-but-set-variable";
meta = with lib; {
description = "Light, portable C library for websockets";
longDescription = ''
Libwebsockets is a lightweight pure C library built to
use minimal CPU and memory resources, and provide fast
throughput in both directions.
'';
homepage = "https://libwebsockets.org/";
license = licenses.lgpl21;
platforms = platforms.all;
};
};
in
rec {
libwebsockets_3_1 = generic {
sha256 = "1w1wz6snf3cmcpa3f4dci2nz9za2f5rrylxl109id7bcb36xhbdl";
version = "3.1.0";
};
libwebsockets_3_2 = generic {
version = "3.2.2";
sha256 = "0m1kn4p167jv63zvwhsvmdn8azx3q7fkk8qc0fclwyps2scz6dna";
};
libwebsockets_4_0 = generic {
version = "4.0.21";
sha256 = "01k05x4711ngin598jr9dag4ml3m7hi6pkgr4dsb02ryh1kc6146";
};
}
|