1 files changed, 31 insertions, 0 deletions
diff --git a/pkgs/applications/office/atlassian-cli/default.nix b/pkgs/applications/office/atlassian-cli/default.nix
new file mode 100644
index 000000000000..a56c15bffb2a
--- /dev/null
+++ b/pkgs/applications/office/atlassian-cli/default.nix
@@ -0,0 +1,31 @@
+{ stdenv, fetchzip, jre }:
+stdenv.mkDerivation {
+  name = "atlassian-cli";
+  version = "7.8.0";
+  src = fetchzip {
+    url            = https://bobswift.atlassian.net/wiki/download/attachments/16285777/atlassian-cli-7.8.0-distribution.zip;
+    sha256         = "111s4d9m6vxq8jwh1d6ar1f4n5zmyjg7gi2vl3aq63kxbfld9vw7";
+    extraPostFetch = "chmod go-w $out";
+  };
+  tools = [ "agile" "bamboo" "bitbucket" "confluence" "csv"
+    "hipchat" "jira" "servicedesk" "structure" "tempo" "trello" "upm" ];
+  installPhase = ''
+    mkdir -p $out/{bin,share/doc/atlassian-cli}
+    cp -r lib $out/share/java
+    cp -r README.txt license $out/share/doc/atlassian-cli
+    for tool in $tools
+    do
+      substitute ${./wrapper.sh} $out/bin/$tool \
+        --subst-var out \
+        --subst-var-by jre ${jre} \
+        --subst-var-by tool $tool
+      chmod +x $out/bin/$tool
+    done
+  '';
+  meta = with stdenv.lib; {
+    description = "An integrated family of CLI’s for various Atlassian applications";
+    homepage    = https://bobswift.atlassian.net/wiki/spaces/ACLI/overview;
+    maintainers = [ maintainers.twey ];
+    license     = [ licenses.unfreeRedistributable ];
+  };
+}