wineStaging: add derivation

2 files changed, 35 insertions, 0 deletions

diff --git a/pkgs/misc/emulators/wine/staging.nix b/pkgs/misc/emulators/wine/staging.nix
new file mode 100644
index 000000000000..2aa588592ac1
--- /dev/null
+++ b/pkgs/misc/emulators/wine/staging.nix
@@ -0,0 +1,29 @@
+{ stdenv, fetchFromGitHub, wine, perl, autoconf, utillinux
+, pulseaudio, libtxc_dxtn }:
+
+let version = "1.7.40";
+    patch = fetchFromGitHub {
+      owner = "wine-compholio";
+      repo = "wine-staging";
+      rev = "v${version}";
+      sha256 = "0l14yy6wbvbs2xrnn9z3a35lbnpl8ibkmc0vh983fimf9nxckpan";
+    };
+
+in assert (builtins.parseDrvName wine.name).version == version;
+
+stdenv.lib.overrideDerivation wine (self: {
+  nativeBuildInputs = [ pulseaudio libtxc_dxtn ] ++ self.nativeBuildInputs;
+  buildInputs = [ perl utillinux autoconf ] ++ self.buildInputs;
+
+  name = "${self.name}-staging";
+
+  postPatch = self.postPatch or "" + ''
+    patchShebangs tools
+    cp -r ${patch}/patches .
+    chmod +w patches
+    cd patches
+    patchShebangs gitapply.sh
+    ./patchinstall.sh DESTDIR=.. --all
+    cd ..
+  '';
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 3bfa25de6f3f..3c2d33246504 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -14193,6 +14193,12 @@ let
 
   wine = wineStable;
 
+  wineStaging = callPackage_i686 ../misc/emulators/wine/staging.nix {
+    wine = pkgsi686Linux.wineUnstable;
+    # Patent issues
+    libtxc_dxtn = pkgsi686Linux.libtxc_dxtn_s2tc;
+  };
+
   winetricks = callPackage ../misc/emulators/wine/winetricks.nix {
     inherit (gnome2) zenity;
   };