x16-rom: init at 38

1 files changed, 46 insertions, 0 deletions

diff --git a/pkgs/misc/emulators/commander-x16/rom.nix b/pkgs/misc/emulators/commander-x16/rom.nix
new file mode 100644
index 000000000000..5da77ebceefe
--- /dev/null
+++ b/pkgs/misc/emulators/commander-x16/rom.nix
@@ -0,0 +1,46 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, cc65
+}:
+
+stdenv.mkDerivation rec {
+  pname = "x16-rom";
+  version = "38";
+
+  src = fetchFromGitHub {
+    owner = "commanderx16";
+    repo = pname;
+    rev = "r${version}";
+    sha256 = "xaqF0ppB7I7ST8Uh3jPbC14uRAb/WH21tHlNeTvYpoI=";
+  };
+
+  nativeBuildInputs = [ cc65 ];
+
+  postPatch = ''
+    patchShebangs scripts/
+  '';
+
+  dontConfigure = true;
+
+  installPhase = ''
+    runHook preInstall
+    install -D --mode 444 --target-directory $out/share/${pname} build/x16/rom.bin
+    install -D --mode 444 --target-directory $out/share/doc/${pname} README.md
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.commanderx16.com/forum/index.php?/home/";
+    description = "ROM file for CommanderX16 8-bit computer";
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ AndersonTorres ];
+    platforms = cc65.meta.platforms;
+  };
+
+  passthru = {
+    # upstream project recommends emulator and rom synchronized;
+    # passing through the version is useful to ensure this
+    inherit version;
+  };
+}