nemu: Init at 2.3.0

Signed-off-by: Matthias Beyer <mail@beyermatthias.de>

2 files changed, 67 insertions, 0 deletions

diff --git a/pkgs/applications/misc/nemu/default.nix b/pkgs/applications/misc/nemu/default.nix
new file mode 100644
index 000000000000..669445825f1d
--- /dev/null
+++ b/pkgs/applications/misc/nemu/default.nix
@@ -0,0 +1,65 @@
+{ stdenv, lib, fetchFromGitHub
+, cmake, pkgconfig, gettext
+, ncurses, sqlite, libusb, udev
+
+, libxml2 ? null
+, libarchive ? null
+, graphviz ? null
+, dbus ? null
+
+, debugBuild ? false
+, ovfSupport ? true
+, saveVMSupport ? false
+, withVNCClientSupport ? true
+, withSpice ? true
+, withNetworkMap ? false
+, withDbus ? false
+}:
+
+assert ovfSupport     -> libxml2    != null;
+assert ovfSupport     -> libarchive != null;
+assert withNetworkMap -> graphviz   != null;
+assert withDbus       -> dbus       != null;
+
+stdenv.mkDerivation rec {
+  pname = "nemu";
+  version = "2.3.0";
+
+  src = fetchFromGitHub {
+    owner = "nemuTUI";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "1wyps72w59mh3bjx533qy88wypyg95gwkmyf7p67xxdlfwbjgvv5";
+  };
+
+  nativeBuildInputs = [ cmake pkgconfig gettext ];
+
+  buildInputs = [ ncurses sqlite libusb udev libxml2 ]
+    ++ (lib.optional ovfSupport     libarchive)
+    ++ (lib.optional withNetworkMap graphviz)
+    ++ (lib.optional withDbus       dbus);
+
+  cmakeFlags = []
+    ++ (lib.optional debugBuild "-DNM_DEBUG=ON")
+    ++ (lib.optional ovfSupport "-DNM_WITH_OVF_SUPPORT=ON")
+    ++ (lib.optional saveVMSupport "-DNM_SAVEVM_SNAPSHOTS=ON")
+    ++ (lib.optional withVNCClientSupport "-DNM_WITH_VNC_CLIENT=ON")
+    ++ (lib.optional withSpice "-DNM_WITH_SPICE=ON")
+    ++ (lib.optional withNetworkMap "-DNM_WITH_NETWORK_MAP=ON")
+    ++ (lib.optional withDbus "-DNM_WITH_DBUS=ON")
+    ;
+
+  installPhase = ''
+    mkdir -p $out/bin/
+    cp nemu $out/bin/
+  '';
+
+  meta = {
+    homepage = "https://github.com/nemuTUI/nemu";
+    description = "Ncurses UI for QEMU";
+    license = stdenv.lib.licenses.bsd2;
+    maintainers = [ stdenv.lib.maintainers.matthiasbeyer ];
+    platforms = with stdenv.lib.platforms; linux;
+  };
+}
+
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index fb49cde2e6bb..0c867a986e25 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5289,6 +5289,8 @@ in
 
   ipcalc = callPackage ../tools/networking/ipcalc {};
 
+  nemu = callPackage ../applications/misc/nemu {};
+
   netmask = callPackage ../tools/networking/netmask {};
 
   netifd = callPackage ../tools/networking/netifd {};