blob: af9e7050267883bdd0504aa8b754e2e568eb6322 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
CALL :REALPATH %~dp0\..
SET MIXXX_ROOT=%RETVAL%
IF NOT DEFINED PLATFORM (
SET PLATFORM=x64
)
IF NOT DEFINED CONFIGURATION (
SET CONFIGURATION=release-fastbuild
)
IF NOT DEFINED BUILDENV_BASEPATH (
SET BUILDENV_BASEPATH=%MIXXX_ROOT%\buildenv
)
CALL :COMMAND_%1
EXIT /B 0
:COMMAND_name
CALL :READ_ENVNAME
ECHO "%RETVAL%"
IF DEFINED GITHUB_ENV (
ECHO BUILDENV_NAME=!RETVAL! >> !GITHUB_ENV!
)
GOTO :EOF
:COMMAND_setup
CALL :READ_ENVNAME
SET BUILDENV_NAME=%RETVAL%
SET BUILDENV_PATH=%BUILDENV_BASEPATH%\%BUILDENV_NAME%
IF NOT EXIST %BUILDENV_BASEPATH% (
MD %BUILDENV_BASEPATH%
)
IF NOT EXIST %BUILDENV_PATH% (
SET BUILDENV_URL=https://downloads.mixxx.org/builds/buildserver/2.3.x-windows/%BUILDENV_NAME%.zip
IF NOT EXIST !BUILDENV_PATH!.zip (
ECHO Downloading !BUILDENV_URL!
BITSADMIN /transfer buildenvjob /download /priority normal !BUILDENV_URL! !BUILDENV_PATH!.zip
REM TODO: verify download using sha256sum?
)
ECHO Unpacking !BUILDENV_PATH!.zip
CALL :UNZIP "!BUILDENV_PATH!.zip" "!BUILDENV_BASEPATH!"
ECHO Unpacking complete.
DEL /f /q %BUILDENV_PATH%.zip
)
ECHO Using build environment: !BUILDENV_PATH!
ENDLOCAL
SET PATH=!BUILDENV_PATH!\bin;!PATH!
FOR /D %%G IN (%BUILDENV_PATH%\Qt-*) DO (SET Qt5_DIR=%%G)
SET CMAKE_PREFIX_PATH=!BUILDENV_PATH!;!Qt5_DIR!
ECHO ^Environent Variables:
ECHO ^- PATH=!PATH!
ECHO ^CMake Configuration:
ECHO ^- CMAKE_PREFIX_PATH=!CMAKE_PREFIX_PATH!
IF DEFINED GITHUB_ENV (
ECHO CMAKE_PREFIX_PATH=!CMAKE_PREFIX_PATH!>>!GITHUB_ENV!
ECHO PATH=!PATH!>>!GITHUB_ENV!
)
GOTO :EOF
:UNZIP <newzipfile> <ExtractTo>
SET vbs="%temp%\_.vbs"
IF EXIST %vbs% del /f /q %vbs%
>%vbs% echo Set fso = CreateObject("Scripting.FileSystemObject")
>>%vbs% echo If NOT fso.FolderExists(%2) Then
>>%vbs% echo fso.CreateFolder(%2)
>>%vbs% echo End If
>>%vbs% echo Set objShell = CreateObject("Shell.Application")
>>%vbs% echo Set FilesInZip=objShell.NameSpace(%1).items
>>%vbs% echo objShell.NameSpace(%2).CopyHere(FilesInZip)
>>%vbs% echo Set fso = Nothing
>>%vbs% echo Set objShell = Nothing
cscript //nologo %vbs%
IF EXIST %vbs% DEL /f /q %vbs%
GOTO :EOF
:REALPATH
SET RETVAL=%~f1
GOTO :EOF
:READ_ENVNAME
SET /P BUILDENV_NAME=<%MIXXX_ROOT%\cmake\windows_build_environment_name
SET BUILDENV_NAME=!BUILDENV_NAME:PLATFORM=%PLATFORM%!
SET BUILDENV_NAME=!BUILDENV_NAME:CONFIGURATION=%CONFIGURATION%!
SET RETVAL=%BUILDENV_NAME%
GOTO :EOF
|
