blob: 276b1dc317652a124fc66dcd9dc89f76b87c7b38 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
#version 330 core
layout (location = 0) in vec2 position;
// Cell properties
layout (location = 1) in vec2 gridCoords;
// glyph properties
layout (location = 2) in vec4 glyph;
// uv mapping
layout (location = 3) in vec4 uv;
// text fg color
layout (location = 4) in vec3 textColor;
out vec2 TexCoords;
out vec3 fg;
// Terminal properties
uniform vec2 termDim;
uniform vec2 cellDim;
uniform vec2 cellSep;
// Orthographic projection
uniform mat4 projection;
void main()
{
vec2 glyphOffset = glyph.xy;
vec2 glyphSize = glyph.zw;
vec2 uvOffset = uv.xy;
vec2 uvSize = uv.zw;
// Position of cell from top-left
vec2 cellPosition = (cellDim + cellSep) * gridCoords;
// Invert Y since framebuffer origin is bottom-left
cellPosition.y = termDim.y - cellPosition.y - cellDim.y;
// Glyphs are offset within their cell; account for y-flip
vec2 cellOffset = vec2(glyphOffset.x,
glyphOffset.y - glyphSize.y);
// position coordinates are normalized on [0, 1]
vec2 finalPosition = glyphSize * position + cellPosition + cellOffset;
gl_Position = projection * vec4(finalPosition.xy, 0.0, 1.0);
TexCoords = uvOffset + vec2(position.x, 1 - position.y) * uvSize;
fg = textColor / vec3(255.0, 255.0, 255.0);
}
|
