flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105

{
  description = "The pixi package manager";
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-23.05";
    flake-utils.url = "github:numtide/flake-utils";
    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
  };

  outputs = inputs: inputs.flake-utils.lib.eachDefaultSystem
    (system:
      let
        pkgs = import inputs.nixpkgs {
          inherit system;
          overlays = [ (import inputs.rust-overlay) ];
        };

        rustTarget = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
        craneLib = (inputs.crane.mkLib pkgs).overrideToolchain rustTarget;
        tomlInfo = craneLib.crateNameFromCargoToml { cargoToml = ./Cargo.toml; };
        src = pkgs.nix-gitignore.gitignoreSource [ ] ./.;

        cargoArtifacts = craneLib.buildDepsOnly {
          inherit src;
          inherit (tomlInfo) pname version;

          buildInputs = [
            pkgs.pkg-config
            pkgs.openssl
            pkgs.cmake
          ];
        };

        pixi = craneLib.buildPackage {
          inherit cargoArtifacts src;
          inherit (tomlInfo) pname version;

          cargoExtraArgs = "--all-features";

          buildInputs = [
            pkgs.pkg-config
            pkgs.openssl
            pkgs.cmake
          ];

          doCheck = false;
        };
      in
      rec {
        checks = {
          inherit pixi;

          pixi-clippy = craneLib.cargoClippy {
            inherit cargoArtifacts src;
            inherit (tomlInfo) pname version;
            cargoClippyExtraArgs = "--benches --examples --tests --all-features -- --deny warnings";
          };

          pixi-clippy-no-features = craneLib.cargoClippy {
            inherit cargoArtifacts src;
            inherit (tomlInfo) pname version;
            cargoClippyExtraArgs = "--benches --examples --tests --no-default-features -- --deny warnings";
          };

          pixi-fmt = craneLib.cargoFmt {
            inherit cargoArtifacts src;
            inherit (tomlInfo) pname version;
          };
        };

        packages = {
          default = packages.pixi;
          inherit pixi;
        };

        apps = {
          pixi = inputs.flake-utils.lib.mkApp {
            drv = pixi;
          };
        };

        devShells.default = devShells.pixi;
        devShells.pixi = pkgs.mkShell {
          buildInputs = [
            pkgs.pkg-config
            pkgs.openssl
            pkgs.cmake
          ];

          nativeBuildInputs = [
            rustTarget
          ];
        };
      }
    );
}