blob: 5c0bd028d95cfb9bc3dc1bc5a91f74620ac80c24 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# This file is part of Mixxx, Digital DJ'ing software.
# Copyright (C) 2001-2023 Mixxx Development Team
# Distributed under the GNU General Public Licence (GPL) version 2 or any later
# later version. See the LICENSE file for details.
#[=======================================================================[.rst:
FindSoundTouch
--------------
Finds the SoundTouch library.
Imported Targets
^^^^^^^^^^^^^^^^
This module provides the following imported targets, if found:
``SoundTouch::SoundTouch``
The SoundTouch library
Result Variables
^^^^^^^^^^^^^^^^
This will define the following variables:
``SoundTouch_FOUND``
True if the system has the SoundTouch library.
``SoundTouch_INCLUDE_DIRS``
Include directories needed to use SoundTouch.
``SoundTouch_LIBRARIES``
Libraries needed to link to SoundTouch.
``SoundTouch_DEFINITIONS``
Compile definitions needed to use SoundTouch.
Cache Variables
^^^^^^^^^^^^^^^
The following cache variables may also be set:
``SoundTouch_INCLUDE_DIR``
The directory containing ``soundtouch/SoundTouch.h``.
``SoundTouch_LIBRARY``
The path to the SoundTouch library.
#]=======================================================================]
find_package(PkgConfig QUIET)
if(PkgConfig_FOUND)
pkg_check_modules(PC_SoundTouch QUIET soundtouch)
endif()
find_path(SoundTouch_INCLUDE_DIR
NAMES soundtouch/SoundTouch.h
PATHS ${PC_SoundTouch_INCLUDE_DIRS}
DOC "SoundTouch include directory")
mark_as_advanced(SoundTouch_INCLUDE_DIR)
find_library(SoundTouch_LIBRARY
NAMES SoundTouch
PATHS ${PC_SoundTouch_LIBRARY_DIRS}
DOC "SoundTouch library"
)
mark_as_advanced(SoundTouch_LIBRARY)
# Version detection
if(DEFINED PC_SoundTouch_VERSION AND NOT PC_SoundTouch_VERSION STREQUAL "")
set(SoundTouch_VERSION "${PC_SoundTouch_VERSION}")
else()
if(EXISTS "${SoundTouch_INCLUDE_DIR}/soundtouch/SoundTouch.h")
file(READ "${SoundTouch_INCLUDE_DIR}/soundtouch/SoundTouch.h" SoundTouch_H_CONTENTS)
string(REGEX MATCH "#define SOUNDTOUCH_VERSION[ \t]+\"([0-9]+\.[0-9]+\.[0-9]+)\"" _dummy "${SoundTouch_H_CONTENTS}")
set(SoundTouch_VERSION "${CMAKE_MATCH_1}")
endif()
endif()
include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(
SoundTouch
REQUIRED_VARS SoundTouch_LIBRARY SoundTouch_INCLUDE_DIR
VERSION_VAR SoundTouch_VERSION
)
if(SoundTouch_FOUND)
set(SoundTouch_LIBRARIES "${SoundTouch_LIBRARY}")
set(SoundTouch_INCLUDE_DIRS "${SoundTouch_INCLUDE_DIR}")
set(SoundTouch_DEFINITIONS ${PC_SoundTouch_CFLAGS_OTHER})
if(NOT TARGET SoundTouch::SoundTouch)
add_library(SoundTouch::SoundTouch UNKNOWN IMPORTED)
set_target_properties(SoundTouch::SoundTouch
PROPERTIES
IMPORTED_LOCATION "${SoundTouch_LIBRARY}"
INTERFACE_COMPILE_OPTIONS "${PC_SoundTouch_CFLAGS_OTHER}"
INTERFACE_INCLUDE_DIRECTORIES "${SoundTouch_INCLUDE_DIR}"
)
endif()
endif()
|